日志标签:ADO→XML

利用XSLT把ADO记录集转换成XML

时间:2011年07月22日作者:小侃评论次数:0

由于XML(可扩展标记语言:eXtensible Markup Language)真正的平台无关性,它正在逐渐成为数据传输的主要介质。XML是一种自描述的语言,数据本身就已经包含了元数据,即关于数据本身的信 息。例如:“孟子E章1757281793923net_lover1807581793923”这组数据,从字面很难看出它代表什么意思,也不清楚它有 几个数据段组成,但是,如果用XML来做如下的描述,我们就可以清楚地看到每个数据段所代表的含义:

<PersonData>
<Person>
<姓名>孟子E章</姓名>
<身高>175</身高>
<体重>72</体重>
<电话>81793923</电话>
</Person>
<Person>
<姓名>net_lover</姓名>
<身高>180</身高>
<体重>75</体重>
<电话>81793923</电话>
</Person>
</PersonData>

从上面的一段XML中,我们不但可以清楚地看到每一个数据代表的是什么意思了,而且还可以知道数据的分割位置。在我们平常的应用中,我们得到的结果可能是 数组、集合或记录集的表现形式,我们该如何把它们转换成自描述的XML格式的数据呢?从数据形式上看,XML是简单的纯字符串的文本格式,字符串在传递时 是非常简单、快速而且是容易的,数组在通过引用进行传递时有时是很慢的,而且处理起来很麻烦,而集合和记录集都是对象,在处理时会导致计算机性能的下降, 并且这些对象都是与特定的平台相关联的,这就要求平台有内建的处理机制来处理对象的操作。XML已经是W3C的标准,是平台无关的,我们的计算机的唯一要 求就是能够处理简单的XML字符串,即XML解析器,它能够解析XML字符串,能够通过一种接口很容易地把数据分解成一个个独立的数据段,以便我们能够进 行访问。XML解析器都很小,性能也很好,在每种平台上都可以找到。一旦我们接收到XML数据并把它解析成上面的例子的样式后,我们就可以通过 XSLT(eXstensible Stylesheet Language Transformations)把他们转换成不同的表现形式。利用XML的数据格式进行数据传输,将会使我们编写应用程序代码的工作更简单轻松,而且具 有良好的可伸缩性。
下面,我们就看看如何来转换我们的数据。我们的例子是在Microsoft Windows 2000,IIS5,MSXML3和ADO2.6下编写的,样例数据采用Microsoft SQL Server7.0自带的Northwind示例数据库。之所以采用SQL Server7而不采用支持XML的SQL Server2000,是考虑到通用性的原则,我们的目的是:处理不同类型的数据源得到的记录集,而不仅仅是象SQL Server2000那样的支持XML输出的数据源。使用ADO,是因为它形式多样,可以处理不同类型的数据源;使用XML,是因为它能够快速传输和解 析。但本例的处理方法也适合在任何具有Micrsoft XML解析器,ADO2.5或以上版本的Windows,IIS,SQL Server的环境中。
为简单起见,我们仅选择单价小于等于20美圆,库存大于等于20,产品名称小于等于6个字符的产品:

<%
Dim objRecordset
Set objRecordset = Server.CreateObject(“ADODB.Recordset”)
objRecordset.open _
“SELECT ProductName, UnitPrice, UnitsInStock ” _
& “FROM Products ” _
& “WHERE UnitPrice <= 20 ” _
& “AND UnitsInStock >= 20 ” _
& “AND LEN(ProductName) <= 6 ” _
& “ORDER BY ProductName”, _
“Provider=SQLOLEDB;” _
& “Data Source=SomeSQLServer;” _
& “Initial Catalog=Northwind;” _
& “User ID=MyUserName;” _
& “Password=MyPassword;”
%>
现在,我们就用3种方式把我们得到的记录集转换成XML格式。
首先,我们可以遍历整个记录集,采用XML DOM(Document Object Model),建立XML节点树:

<%
Dim objXMLDOM, objRootNode, objNode
Set objXMLDOM = Server.CreateObject(“MSXML2.DOMDocument”)

Set objRootNode = objXMLDOM.createElement(“xml”)
objXMLDOM.documentElement = objRootNode

Do While NOT objRecordset.EOF
Set objRowNode = objXMLDOM.createElement(“row”)
Set objNode = objXMLDOM.createElement(“ProductName”)
objNode.text = objRecordset.Fields.Item(“ProductName”).Value
objRowNode.appendChild(objNode)

Set objNode = objXMLDOM.createElement(“UnitPrice”)
objNode.text = objRecordset.Fields.Item(“UnitPrice”).Value
objRowNode.appendChild(objNode)

Set objNode = objXMLDOM.createElement(“UnitsInStock”)
objNode.text = objRecordset.Fields.Item(“UnitsInStock”).Value
objRowNode.appendChild(objNode)

objRootNode.appendChild(objRowNode)

objRecordset.MoveNext
Loop

Set objNode = Nothing
Set objRowNode = Nothing
Set objRootNode = Nothing

Set objRecordset = Nothing
%>

现在,我们就得到了一个XML DOM对象。这种方法对于记录集很大时性能并不理想,因为系统内存中要同时保存ADO记录集对象和XML DOM对象。
第二个办法,遍历记录集,直接生成XML字符串本身:

<%
Dim strXML
strXML = “<xml>”
objRecordset.MoveFirst
Do While NOT objRecordset.EOF
strXML = strXML & “<row>”
strXML = strXML & “<ProductName>” _
& objRecordset.Fields.Item(“ProductName”).Value _
& “</ProductName>”
strXML = strXML & “<UnitPrice>” _
& objRecordset.Fields.Item(“UnitPrice”).Value _
& “</UnitPrice>”
strXML = strXML & “<UnitsInStock>” _
& objRecordset.Fields.Item(“UnitsInStock”).Value _
& “</UnitsInStock>”
strXML = strXML & “</row>”
objRecordset.MoveNext
Loop
strXML = strXML & “</xml>”
Set objRecordset = Nothing
%>

但是,以上两种方法最大的缺陷是不能够重用代码,我们把节点的名字都写死了,如果我们进行不同字段的查询,我们还必须手动更改我们的代码,以满足不同节点的需要。我们下面的方法将变得更加通用。
第三种方法:可重用的方法。

<%
Dim strXML
strXML = “<xml>”
objRecordset.MoveFirst
Do While NOT objRecordset.EOF
strXML = strXML & “<row>”
For Each varItem In objRecordset.Fields
strXML = strXML _
& “<” & varItem.name & “>” _
& varItem.value _
& “</” & varItem.name & “>”
Next
strXML = strXML & “</row>”
objRecordset.MoveNext
Loop
strXML = strXML & “</xml>”
Set objRecordset = Nothing
%>

一个更有效的方法,我们可以直接利用记录集内建的save方法,它能够自动地把记录集的内容转换成XML格式,我们调用save方法后,我们就可以立即释 放内存中的记录集对象实例。 save方法有两个参数:一个是XML要保存的地方,一个是指示符,标明数据以何种格式保存。我们可以把数据保存成XML DOM对象(ADO STREAM对象),也可以直接保存成ASP RESPONSE对象,为通用起见,我们保存成XML DOM,第二个参数用adPersistXML ADO常量。方法如下:

<%
Const adPersistXML = 1
Dim objXMLDOM
Set objXMLDOM = Server.CreateObject(“MSXML2.DOMDocument.3.0″)
objRecordset.save objXMLDOM, adPersistXML
Set objRecordset = Nothing
%>

这种方法方便快捷,而且不容易出错,对不同的查询,也不用手动更改节点名字。但是,这种方法产生的XML不够简洁,看看它产生的结果:

<xml
xmlns:s=”uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882″
xmlns:dt=”uuid:C2F41010-65B3-11d1-A29F-00AA00C14882″
xmlns:rs=”urn:schemas-microsoft-com:rowset”
xmlns:z=”#RowsetSchema”>

<s:Schema id=”RowsetSchema”>

<s:ElementType
name=”row”
content=”eltOnly”
rs:CommandTimeout=”30″>

<s:AttributeType
name=”ProductName”
rs:number=”1″
rs:writeunknown=”true”>

<s:datatype
dt:type=”string”
dt:maxLength=”40″
rs:maybenull=”false”/>
</s:AttributeType>

<s:AttributeType
name=”UnitPrice”
rs:number=”2″
rs:nullable=”true”
rs:writeunknown=”true”>

<s:datatype
dt:type=”number”
rs:dbtype=”currency”
dt:maxLength=”8″
rs:precision=”19″
rs:fixedlength=”true”/>
</s:AttributeType>

<s:AttributeType
name=”UnitsInStock”
rs:number=”3″
rs:nullable=”true”
rs:writeunknown=”true”>

<s:datatype
dt:type=”i2″
dt:maxLength=”2″
rs:precision=”5″
rs:fixedlength=”true”/>
</s:AttributeType>

<s:extends type=”rs:rowbase”/>

</s:ElementType>

</s:Schema>

<rs:data>

<z:row
ProductName=”Chai”
UnitPrice=”18″
UnitsInStock=”39″/>

<z:row
ProductName=”Konbu”
UnitPrice=”6″
UnitsInStock=”24″/>

<z:row
ProductName=”Tofu”
UnitPrice=”23.25″
UnitsInStock=”35″/>

</rs:data>

</xml>

ADO自动产生的XML包含了schema信息,它描述这个XML里允许有什么节点和属性以及采用何种数据类型,而且数据节点也增加了名称空间。 schema信息在需要数据验证的地方或进行更复杂的处理或许很有用,但是,大多数情况下,我们使用的是瘦客户机,我们不需要schema信息。我们可以 利用XSLT来分离出我们想要的信息,去掉多余的信息。因此,我们编写下面的“ DataCleaner.xsl”:

<?xml version=”1.0″?>
<xsl:stylesheet version=”1.0″
xmlns:xsl=”http://www.w3.org/1999/XSL/Transform”
xmlns:s=”uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882″
xmlns:dt=”uuid:C2F41010-65B3-11d1-A29F-00AA00C14882″
xmlns:rs=”urn:schemas-microsoft-com:rowset”
xmlns:z=”#RowsetSchema”>

<xsl:output omit-xml-declaration=”yes”/>
<xsl:template match=”/”>
<xsl:element name=”xml”>
<xsl:for-each select=”/xml/rs:data/z:row”>
<xsl:element name=”row”>
<xsl:for-each select=”@*”>
<xsl:element name=”{name()}”>
<xsl:value-of select=”.”/>
</xsl:element>
</xsl:for-each>
</xsl:element>
</xsl:for-each>
</xsl:element>
</xsl:template>

</xsl:stylesheet>

这个XSLT具有可重用的特性,对于不同的查询结果都适用,下面就是如何使用这个XSLT的例子:

<%
Dim strCleanXML, objXMLDOM_XSLT

Set objXMLDOM_XSLT = CreateObject(“MSXML2.DOMDocument”)
objXMLDOM_XSLT.load(Server.MapPath(“DataCleaner.xsl”))
strCleanXML = objXMLDOM.transformNode(objXMLDOM_XSLT)

Set objXMLDOM = Nothing
Set objXMLDOM_XSLT = Nothing
%>

经过上面的处理以后,strClaenXML就是我们所想要的XML字符串了。

<xml>
<row>
<ProductName>Chai</ProductName>
<UnitPrice>18</UnitPrice>
<UnitsInStock>39</UnitsInStock>
</row>
<row>
<ProductName>Konbu</ProductName>
<UnitPrice>6</UnitPrice>
<UnitsInStock>24</UnitsInStock>
</row>
</xml>

上面这种格式的XML字符串是我们经常见到的节点集的样式,如果您不想把字段处理成节点,而把它处理成属性节点,那么我们只需对DataCleaber.xsl稍加改动即可:

<?xml version=”1.0″?>
<xsl:stylesheet version=”1.0″
xmlns:xsl=”http://www.w3.org/1999/XSL/Transform”
xmlns:s=”uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882″
xmlns:dt=”uuid:C2F41010-65B3-11d1-A29F-00AA00C14882″
xmlns:rs=”urn:schemas-microsoft-com:rowset”
xmlns:z=”#RowsetSchema”>

<xsl:output omit-xml-declaration=”yes”/>

<xsl:template match=”/”>
<xsl:element name=”xml”>
<xsl:for-each select=”/xml/rs:data/z:row”>
<xsl:element name=”row”>
<xsl:for-each select=”@*”>
<xsl:attribute name=”{name()}”>
<xsl:value-of select=”.”/>
</xsl:attribute>
</xsl:for-each>
</xsl:element>
</xsl:for-each>
</xsl:element>
</xsl:template>

</xsl:stylesheet>

以下是采用了新样式的结果,它比用节点表示字段的长度要短的多了。传输起来速度会更快:

<xml>
<row ProductName=”Chai” UnitPrice=”18″ UnitsInStock=”39″/>
<row ProductName=”Konbu” UnitPrice=”6″ UnitsInStock=”24″/>
</xml>

到此为止,我们介绍了从ADO 记录集得到XML格式数据的几种办法,也得到了最简化的字符串。但是有几个问题你仍然需要注意,有些字段值还有XML里不支持的字符,比 如:”‘<>&,象P&G宝洁公司的名称,Chef Anton’s Gumbo Mix产品名字等,在做转换时要进行编码处理。在Microsoft ADO 2.6的SDK里有使用save方法时要注意的问题:1,save方法只对open Recordset起作用;2,不支持带有adVariant,adIDispatch,adIUnknown类型的字段的记录集的savw;3,当保存 分级的记录集( data shapes)有两个限制:不能保存参数化和含有未解决的更新的记录集。
为了更进一步提高性能,你可以把转换工作放到COM/COM+组件中, ASP代码只进行数据的最终表现即可。把业务层、数据层和表现层分开,ASP只需要调用数据组件,数据组件调用数据库的存储过程,把结果转换成XML,最 后只把简单的XML字符环串回到ASP程序里,ASP就可以用XSLT把XML进行转换,把结果送到浏览器。

标签:分类:WEB程序开发